sieve est malheureusement un grand oublié des serveurs IMAP. Peu de monde connaît ce petit langage qui pourtant peut rendre d'immenses services comme trier automatiquement le spam, les publicités, ou même renvoyer un message d'absence lorsque vous êtes en vacance. Voici donc un petit panorama pour régler cette injustice.

require ["reject", "fileinto", "comparator-iascii-numeric", "relational", "imapflags"]

if header :contains ["X-Spam-Level"] ["**"]
{
    fileinto "INBOX.Spams"
    stop
}

D'un coup on comprends mieux à quoi cet outil peut servir. Sieve est donc un langage permettant divers opérations sur les courriels reçus par le serveur IMAP. Dans notre exemple, il analyse le header de chaque message et s'il s'agit d'un spam, le pause directement dans la sous-boîte spams. En gros, sieve permet de faire à peu près tout ce que permettent les classiques fonctions de filtrage des clients courriels, ais de manière automatique, au niveau du serveur lui-même. Ainsi, grâce à des scripts sieve bien construits, le mail est directement ventilé dans les sous boîtes, même avec un accès de type webMail.

Sieve dans cyrus

D'un point de vue physique, sieve est un sous-serveur de cyrus placé sur le port 2000, il est activé dans le fichier /etc/cyrus.conf qui doit contenir la ligne suivante :

sieve         cmd="timsieved" listen="sieve" prefork=1

Ensuite il faut simplement relancer cyrus (service cyrus-imapd restart) pour constate l'arrivé du serveur sieve (netstat -anlp | grep 2000).

Création des scripts

Comme sieve est un serveur, vous pouvez acceder aux scripts à distance. Le moyen le plus simple que j'ai trouvé c'est un module KIOSLAVE dédié de KDE. Pour ceux qui ne connaissent l'architecture KIO de KDE est proprement géniale. En effet, KDE fournit une interface de type plugin pour prendre en charge les protocoles de lecture et décriture de fichier ou de dossier. Par exemple, si vous prenez konqueror et que vous tappez dans l'url imap://mon_login@mon_serveur_imap vous avez accès, après autentification, à vos mails en lecture...De la même manière vous pouvez accedez aux scritps sieve d'un compte par l'url sieve://mon_login_sieve@.

Logiquement donc, konqueror devrait après autentification afficher une page vide. Il n'y a en effet pour l'instant aucun script pour ce compte imap. Pour en créer un, clique droit et nouveau document texte que vous appellerez default.

Maintenant, très simplement, vous double-cliqué sur ce fichier default, qui s'ouvre sans broncher avec un éditeur de texte comme kwrite et vous pouvez éditer votre script. A chaque sauvegarde, votre travail est envoyé sur le serveur sieve, compilé et immédiatement actif. S'il y a une erreur de syntaxe, kwrite vous donnera même la ligne de l'erreur. Magique non ?

Petite vérification d'usage pour vérifier que le script est bien actif :

sieveshell -u toto -a toto serveur_sieve
# affichage du prompt sieve, on veut la liste des scripts de toto
list
#    default

# on constate que le script n'est pas actif !
activate default
list

quit

Brêve explication de la syntaxe

Un script sieve commence par la déclaration des librairies pré-requises :

# importation des bibliothèques utiles
require ["reject", "fileinto", "comparator-iascii-numeric", "relational", "imapflags"]

Ensuite, vous pouvez inserez vos règles sous la forme de tests :

if BLOC_CONDITION
{
   ACTION_1
   ...
   ACTION_N
}

Les actions les plus "utiles" sont :

discard

qui entraine la destruction du courriel ayant vérifié la condition.

stop

qui, si la conditon est vérifié, demande à sieve de ne plus regarder les autres règles pour le message.

fileinto "NOM_BOITE"

qui déplace le courriel dans une autre boîte IMAP.

BLOC_CONDITION quant à lui peut être une condition simple ou une composition de conditions simples liées entre elle par des ET (allof) ou des OU (anyof) :

# condition simple
if CONDITION_SIMPLE
{
  # liste des actions
}

# conditions liées par OU
if anyof (CONDITION_SIMPLE_1, CONDITION_SIMPLE_2, ..., CONDITION_SIMPLE_N)
{
  # liste des actions
}

# conditions liées par ET
if allof (CONDITION_SIMPLE_1, CONDITION_SIMPLE_2, ..., CONDITION_SIMPLE_N)
{
  # liste des actions
}

une condition simple se compose de l'objet sur lequel porte la condition, d'un type de condition et de paramétres. La syntaxe globale d'une condition simple est donc (notez bien le : et le not optionnel) :

[not] OBJET_CONDITION :TYPE_CONDITION PARAMETRE_CONDITION_1 ... PARAMETRE_CONDITION_N  

Les objets de conditions classiques sont :

header

La condition porte sur un des champs de l'en-tête du message (Received, Subject, etc...)

size

La taille du message

Les paramétres des conditions dépendent quant à eux beaucoup du type de condition. Cela peut être une chaine ("CHAINE"), une taille (1M pour 1mo), un tableau de chaines (["CHAINE_1","CHAINE_2",...,"CHAINE_N"]), etc...

enfin les grand types de condition sont :

contains P1 P2

Vérifie que l'objet est contenu à au moins une valeur de P1 dans la P2. P1 et P2 peuvent être des chaînes pu des tableaux.

matches P1 P2

Comme containes mis à part que P2 peut contenur des chaines avec des jocker (ex. "*@karma-lab.net")

over P1

Opérateur "superieur à" P1

Application, une gestion fine des SPAMS

L'exemple qui suit est une mise en application des principes énoncés plus haut. L'objectif est de filrer les spams flaggés par spamassassin selon 3 niveaux. Les spams de niveau 3 et plus seront détruits, les spams de niveau 2 et les erreurs de trasport de courries lié à l'usurpation d'adresse sont placés dans le dossier "spams", enfin les spams de niveau 1, sont placés dans le dossier "spams.ham".

# spamassassin a taggé le mail de niveau 3, on le détruit donc directement
if header :contains ["X-Spam-Level"] ["***"]
{
  # supression du mail
  discard

  # c'est fini pour lui, on ne cherche pas à exécuter plus loin...  
  stop
}

# Par un composition de conditions de type OU, on cherche maintenant à filtre les autres
# spams pour les placer dans la boite "spam"
if anyof
(
   # si le spam assassin a taggé ce mail de niveau 3
   header :contains ["X-Spam-Level"] ["**"] ,  

   # si le mail est une erreur de distribution de courrier
   allof
   (
      # sujet typique d'une erreur de distribution, on utilise "matches" pour bénéficier de *
      header :matches "Subject" ["failure notice", "Delivery Status Notification*","Returned Mail:*"],
      # on évite de jeter les erreurs de distributions de notre propre FAI
      not header :matches "Received" ["*.mon_fai.fr"]
   )
)
{
  # on déplace le courriel dans la boîte des SPAMS
  fileinto "INBOX.Spams"

  # le traitement s'arrête ici
  stop
}    

# Le spam est de niveau 1, on peut avoir un doute, on le place donc dans le dossier spams.ham
if header :contains ["X-Spam-Level"] ["*"]
{
  # on déplace le courriel dans la boîte des SPAMS
  fileinto "INBOX.Spams.ham"

  # le traitement s'arrête ici
  stop
}

Ce bref apperçu de la syntaxe sieve permet surtout de saisir la puissance du filtrage proposé.

Recettes sieve

Maintenant quelques exemples simples de tests sieve? N'oubliez pas de mettre la ligne require comme indique plus.

On vérifie ici que la courriel est membre d'une mailling-liste (tag List-Id) et selons les cas, on ventile dans différents dossiers :

if header :contains ["List-Id"] ["xorg.lists.freedesktop.org"]
{
  fileinto "INBOX.Mailling-Listes.xorg"
  stop
}

Si le courriel vient d'une adresse donnée, on le place dans un dossier spécial. Noter que "contains" implique *@mon_client.com :

if header :contains ["From"] ["mon_client.com"]
{
  fileinto "INBOX.Mailling-Listes.Ma Societe.mon client"
  stop
}

Si le courriel est destiné à quelqu'un en particulier :

if header :contains ["To"] [""]
{
  fileinto "INBOX.Mailling-Listes.Publicites"
  stop
}

Si le courriel a été reçu via un serveur SMTP (relai) particulier :

if header :contains ["Received"] ["194.211.211.18"]
{
  fileinto "INBOX.Ma Societe"
  stop
}

Si le message est très gros, on le place dans un dossier particulier...

if size :over 1000K
{
  fileinto "INBOX.gros courriels"
  stop
}